init III

2024-10-14 00:08:40 +02:00
parent dbfba56f66
commit 1462d52e13
4572 changed files with 2658864 additions and 0 deletions
--- a/OTRS/Kernel/System/Console/Command/Admin/Package/Export.pm
+++ b/OTRS/Kernel/System/Console/Command/Admin/Package/Export.pm
@@ -0,0 +1,104 @@
+# --
+# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
+# --
+# This software comes with ABSOLUTELY NO WARRANTY. For details, see
+# the enclosed file COPYING for license information (GPL). If you
+# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
+# --
+
+package Kernel::System::Console::Command::Admin::Package::Export;
+
+use strict;
+use warnings;
+
+use parent qw(Kernel::System::Console::BaseCommand);
+
+our @ObjectDependencies = (
+    'Kernel::System::Main',
+    'Kernel::System::Package',
+);
+
+sub Configure {
+    my ( $Self, %Param ) = @_;
+
+    $Self->Description('Export the contents of an OTRS package to a directory.');
+    $Self->AddOption(
+        Name        => 'target-directory',
+        Description => "Export contents of the package to the specified directory.",
+        Required    => 1,
+        HasValue    => 1,
+        ValueRegex  => qr/.*/smx,
+    );
+    $Self->AddArgument(
+        Name        => 'source-path',
+        Description => "Specify the path to an OTRS package (opm) file that should be exported.",
+        Required    => 1,
+        ValueRegex  => qr/.*/smx,
+    );
+
+    return;
+}
+
+sub PreRun {
+    my ( $Self, %Param ) = @_;
+
+    my $SourcePath = $Self->GetArgument('source-path');
+    if ( $SourcePath && !-r $SourcePath ) {
+        die "File $SourcePath does not exist / can not be read.\n";
+    }
+
+    my $TargetDirectory = $Self->GetOption('target-directory');
+    if ( $TargetDirectory && !-d $TargetDirectory ) {
+        die "Directory $TargetDirectory does not exist.\n";
+    }
+
+    return;
+}
+
+sub Run {
+    my ( $Self, %Param ) = @_;
+
+    $Self->Print("<yellow>Exporting package contents...</yellow>\n");
+
+    my $SourcePath = $Self->GetArgument('source-path');
+
+    my $FileString;
+    my $ContentRef = $Kernel::OM->Get('Kernel::System::Main')->FileRead(
+        Location => $SourcePath,
+        Mode     => 'utf8',        # optional - binmode|utf8
+        Result   => 'SCALAR',      # optional - SCALAR|ARRAY
+    );
+    if ( !$ContentRef || ref $ContentRef ne 'SCALAR' ) {
+        $Self->PrintError("File $SourcePath is empty / could not be read.");
+        return $Self->ExitCodeError();
+    }
+    $FileString = ${$ContentRef};
+
+    my %Structure = $Kernel::OM->Get('Kernel::System::Package')->PackageParse(
+        String => $FileString,
+    );
+
+    # just export files if PackageIsDownloadable flag is enable
+    if (
+        defined $Structure{PackageIsDownloadable}
+        && !$Structure{PackageIsDownloadable}->{Content}
+        )
+    {
+        $Self->PrintError("Files cannot be exported.\n");
+        return $Self->ExitCodeError();
+    }
+
+    my $TargetDirectory = $Self->GetOption('target-directory');
+    my $Success         = $Kernel::OM->Get('Kernel::System::Package')->PackageExport(
+        String => $FileString,
+        Home   => $TargetDirectory,
+    );
+
+    if ($Success) {
+        $Self->Print("<green>Exported files of package $SourcePath to $TargetDirectory.</green>\n");
+        return $Self->ExitCodeOk();
+    }
+
+}
+
+1;