andre/scripts
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

init III

Browse Source
This commit is contained in:
Andre Geißler
2024-10-14 00:08:40 +02:00
parent dbfba56f66
commit 1462d52e13
4572 changed files with 2658864 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

133
Perl OTRS/Kernel/System/ITSMChange/Number/AutoIncrement.pm Normal file
View File

@@ -0,0 +1,133 @@
# --
# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
# --
# This software comes with ABSOLUTELY NO WARRANTY. For details, see
# the enclosed file COPYING for license information (GPL). If you
# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
# --
#
# Generates auto increment change numbers like ss.... (e. g. 1010138, 1010139, ...)
# --
package Kernel::System::ITSMChange::Number::AutoIncrement;
use strict;
use warnings;
use parent qw(Kernel::System::ITSMChange::NumberBase);
our @ObjectDependencies = (
'Kernel::Config',
'Kernel::System::DB',
'Kernel::System::ITSMChange',
);
sub IsDateBased {
return 0;
}
sub ChangeNumberBuild {
my ( $Self, $Offset ) = @_;
$Offset ||= 0;
my $BaseCounter = 1;
if ( $Self->ChangeNumberCounterIsEmpty() ) {
$BaseCounter = $Self->InitialCounterOffsetCalculate();
}
my $Counter = $Self->ChangeNumberCounterAdd(
Offset => $BaseCounter + $Offset,
);
return if !$Counter;
my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
my $SystemID = $ConfigObject->Get('SystemID');
my $MinSize = $ConfigObject->Get('ITSMChange::NumberGenerator::AutoIncrement::MinCounterSize')
|| $ConfigObject->Get('ITSMChange::NumberGenerator::MinCounterSize')
|| 5;
# Pad change number with leading '0' to length $MinSize (config option).
$Counter = sprintf "%.*u", $MinSize, $Counter;
my $ChangeNumber = $SystemID . $Counter;
return $ChangeNumber;
}
#
# Calculate initial counter value on (migrated) systems that already have changes,
# but no counter entries yet.
#
sub InitialCounterOffsetCalculate {
my ( $Self, %Param ) = @_;
my $LastChangeNumber = $Self->_GetLastChangeNumber();
return 1 if !$LastChangeNumber;
# If the change number was created by a date based generator, change counter needs to start from 1
return 1 if $Self->_LooksLikeDateBasedChangeNumber($LastChangeNumber);
my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
my $SystemID = $ConfigObject->Get('SystemID');
# Remove SystemID and leading zeros
$LastChangeNumber =~ s{\A $SystemID 0* }{}msx;
return 1 if !$LastChangeNumber;
return $LastChangeNumber + 1;
}
sub _GetLastChangeNumber {
my ( $Self, %Param ) = @_;
my $DBObject = $Kernel::OM->Get('Kernel::System::DB');
return if !$DBObject->Prepare(
SQL => 'SELECT MAX(id) FROM change_item',
);
my $ChangeID;
while ( my @Data = $DBObject->FetchrowArray() ) {
$ChangeID = $Data[0];
}
return if $ChangeID && $ChangeID == 1;
my %Change = $Kernel::OM->Get('Kernel::System::ITSMChange')->ChangeGet(
ChangeID => $ChangeID,
UserID => 1,
LogNo => 1,
);
return if !%Change;
return if !$Change{ChangeNumber};
return $Change{ChangeNumber};
}
sub _LooksLikeDateBasedChangeNumber {
my ( $Self, $ChangeNumber ) = @_;
return if !$ChangeNumber;
my $PossibleDate = substr $ChangeNumber, 0, 8;
return if length $PossibleDate != 8;
# Format possible date as a date string
$PossibleDate =~ s{\A (\d{4}) (\d{2}) (\d{2}) \z}{$1-$2-$3 00:00:00}gsmx;
my $DateTimeObject = $Kernel::OM->Create('Kernel::System::DateTime');
my $Result = $DateTimeObject->Set( String => $PossibleDate );
return if !$Result;
return 1;
}
1;

63
Perl OTRS/Kernel/System/ITSMChange/Number/Date.pm Normal file
View File

@@ -0,0 +1,63 @@
# --
# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
# --
# This software comes with ABSOLUTELY NO WARRANTY. For details, see
# the enclosed file COPYING for license information (GPL). If you
# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
# --
#
# Generates change numbers like yyyymmddss.... (e. g. 200206231010138)
# --
package Kernel::System::ITSMChange::Number::Date;
use strict;
use warnings;
use parent qw(Kernel::System::ITSMChange::NumberBase);
our @ObjectDependencies = (
'Kernel::Config',
);
sub IsDateBased {
return 1;
}
sub ChangeNumberBuild {
my ( $Self, $Offset ) = @_;
$Offset ||= 0;
my $Counter = $Self->ChangeNumberCounterAdd(
Offset => 1 + $Offset,
);
return if !$Counter;
my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
if ( $ConfigObject->Get('ITSMChange::NumberGenerator::Date::UseFormattedCounter') ) {
my $MinSize = $ConfigObject->Get('ITSMChange::NumberGenerator::MinCounterSize')
|| 5;
# Pad change number with leading '0' to length $MinSize (config option).
$Counter = sprintf "%.*u", $MinSize, $Counter;
}
my $DateTimeObject = $Kernel::OM->Create(
'Kernel::System::DateTime'
);
my $DateTimeSettings = $DateTimeObject->Get();
# Create new change number.
my $ChangeNumber = $DateTimeSettings->{Year}
. sprintf( "%.2u", $DateTimeSettings->{Month} )
. sprintf( "%.2u", $DateTimeSettings->{Day} )
. $Counter;
return $ChangeNumber;
}
1;

92
Perl OTRS/Kernel/System/ITSMChange/Number/DateChecksum.pm Normal file
View File

@@ -0,0 +1,92 @@
# --
# Copyright (C) 2001-2019 OTRS AG, https://otrs.com/
# --
# This software comes with ABSOLUTELY NO WARRANTY. For details, see
# the enclosed file COPYING for license information (GPL). If you
# did not receive this file, see https://www.gnu.org/licenses/gpl-3.0.txt.
# --
#
# The algorithm to calculate the checksum is derived from the one
# Deutsche Bundesbahn (german railway company) uses for calculation
# of the check digit of their vehikel numbering.
# The checksum is calculated by alternately multiplying the digits
# with 1 and 2 and adding the resulsts from left to right of the
# vehikel number. The modulus to 10 of this sum is substracted from
# 10. See: http://www.pruefziffernberechnung.de/F/Fahrzeugnummer.shtml
# (german)
#
# Generates change numbers like yyyymmddssID#####C (e. g. 2002062310100011)
package Kernel::System::ITSMChange::Number::DateChecksum;
use strict;
use warnings;
use parent qw(Kernel::System::ITSMChange::NumberBase);
our @ObjectDependencies = (
'Kernel::Config',
);
sub IsDateBased {
return 1;
}
sub ChangeNumberBuild {
my ( $Self, $Offset ) = @_;
$Offset ||= 0;
my $Counter = $Self->ChangeNumberCounterAdd(
Offset => 1 + $Offset,
);
return if !$Counter;
my $ConfigObject = $Kernel::OM->Get('Kernel::Config');
my $SystemID = $ConfigObject->Get('SystemID');
# Pad ticket number with leading '0' to length 5.
$Counter = sprintf "%.5u", $Counter;
my $DateTimeObject = $Kernel::OM->Create(
'Kernel::System::DateTime'
);
my $DateTimeSettings = $DateTimeObject->Get();
# Create new ticket number.
my $ChangeNumber = $DateTimeSettings->{Year}
. sprintf( "%.2u", $DateTimeSettings->{Month} )
. sprintf( "%.2u", $DateTimeSettings->{Day} )
. $SystemID . $Counter;
# Calculate a checksum.
my $CheckSum = 0;
my $Multiply = 1;
for ( my $i = 0; $i < length($ChangeNumber); ++$i ) {
my $Digit = substr( $ChangeNumber, $i, 1 );
$CheckSum = $CheckSum + ( $Multiply * $Digit );
$Multiply += 1;
if ( $Multiply == 3 ) {
$Multiply = 1;
}
}
$CheckSum %= 10;
$CheckSum = 10 - $CheckSum;
if ( $CheckSum == 10 ) {
$CheckSum = 1;
}
$ChangeNumber .= $CheckSum;
return $ChangeNumber;
}
1;