init III

Perl OTRS/Kernel/cpan-lib/Sisimai/Bite/Email/Activehunter.pm

@@ -0,0 +1,167 @@
+package Sisimai::Bite::Email::Activehunter;
+use parent 'Sisimai::Bite::Email';
+use feature ':5.10';
+use strict;
+use warnings;
+
+my $Indicators = __PACKAGE__->INDICATORS;
+my $StartingOf = {
+    'message' => ['  ----- The following addresses had permanent fatal errors -----'],
+    'rfc822'  => ['Content-type: message/rfc822'],
+};
+
+sub headerlist  { return ['X-AHMAILID'] }
+sub description { 'TransWARE Active!hunter' };
+sub scan {
+    # Detect an error from TransWARE Active!hunter
+    # @param         [Hash] mhead       Message headers of a bounce email
+    # @options mhead [String] from      From header
+    # @options mhead [String] date      Date header
+    # @options mhead [String] subject   Subject header
+    # @options mhead [Array]  received  Received headers
+    # @options mhead [String] others    Other required headers
+    # @param         [String] mbody     Message body of a bounce email
+    # @return        [Hash, Undef]      Bounce data list and message/rfc822 part
+    #                                   or Undef if it failed to parse or the
+    #                                   arguments are missing
+    # @since v4.1.1
+    my $class = shift;
+    my $mhead = shift // return undef;
+    my $mbody = shift // return undef;
+
+    # 'from'    => qr/\A"MAILER-DAEMON"/,
+    # 'subject' => qr/FAILURE NOTICE :/,
+    return undef unless defined $mhead->{'x-ahmailid'};
+
+    my $dscontents = [__PACKAGE__->DELIVERYSTATUS];
+    my @hasdivided = split("\n", $$mbody);
+    my $rfc822part = '';    # (String) message/rfc822-headers part
+    my $rfc822list = [];    # (Array) Each line in message/rfc822 part string
+    my $blanklines = 0;     # (Integer) The number of blank lines
+    my $readcursor = 0;     # (Integer) Points the current cursor position
+    my $recipients = 0;     # (Integer) The number of 'Final-Recipient' header
+    my $v = undef;
+
+    for my $e ( @hasdivided ) {
+        # Read each line between the start of the message and the start of rfc822 part.
+        unless( $readcursor ) {
+            # Beginning of the bounce message or delivery status part
+            if( index($e, $StartingOf->{'message'}->[0]) == 0 ) {
+                $readcursor |= $Indicators->{'deliverystatus'};
+                next;
+            }
+        }
+
+        unless( $readcursor & $Indicators->{'message-rfc822'} ) {
+            # Beginning of the original message part
+            if( index($e, $StartingOf->{'rfc822'}->[0]) == 0 ) {
+                $readcursor |= $Indicators->{'message-rfc822'};
+                next;
+            }
+        }
+
+        if( $readcursor & $Indicators->{'message-rfc822'} ) {
+            # After "message/rfc822"
+            unless( length $e ) {
+                $blanklines++;
+                last if $blanklines > 1;
+                next;
+            }
+            push @$rfc822list, $e;
+
+        } else {
+            # Before "message/rfc822"
+            next unless $readcursor & $Indicators->{'deliverystatus'};
+            next unless length $e;
+
+            #  ----- The following addresses had permanent fatal errors -----
+            #
+            # >>> kijitora@example.org <kijitora@example.org>
+            #
+            #  ----- Transcript of session follows -----
+            # 550 sorry, no mailbox here by that name (#5.1.1 - chkusr)
+            $v = $dscontents->[-1];
+
+            if( $e =~ /\A[>]{3}[ \t]+.+[<]([^ ]+?[@][^ ]+?)[>]\z/ ) {
+                # >>> kijitora@example.org <kijitora@example.org>
+                if( $v->{'recipient'} ) {
+                    # There are multiple recipient addresses in the message body.
+                    push @$dscontents, __PACKAGE__->DELIVERYSTATUS;
+                    $v = $dscontents->[-1];
+                }
+                $v->{'recipient'} = $1;
+                $recipients++;
+
+            } else {
+                #  ----- Transcript of session follows -----
+                # 550 sorry, no mailbox here by that name (#5.1.1 - chkusr)
+                next unless $e =~ /\A[0-9A-Za-z]+/;
+                next if length $v->{'diagnosis'};
+                $v->{'diagnosis'} ||= $e;
+            }
+        } # End of if: rfc822
+    }
+
+    return undef unless $recipients;
+    require Sisimai::String;
+
+    for my $e ( @$dscontents ) {
+        $e->{'diagnosis'} = Sisimai::String->sweep($e->{'diagnosis'});
+        $e->{'agent'}     = __PACKAGE__->smtpagent;
+    }
+
+    $rfc822part = Sisimai::RFC5322->weedout($rfc822list);
+    return { 'ds' => $dscontents, 'rfc822' => $$rfc822part };
+}
+
+1;
+__END__
+
+=encoding utf-8
+
+=head1 NAME
+
+Sisimai::Bite::Email::Activehunter - bounce mail parser class for Active!hunter.
+
+=head1 SYNOPSIS
+
+    use Sisimai::Bite::Email::Activehunter;
+
+=head1 DESCRIPTION
+
+Sisimai::Bite::Email::Activehunter parses a bounce email which created by C<TransWARE
+Active!hunter>. Methods in the module are called from only Sisimai::Message.
+
+=head1 CLASS METHODS
+
+=head2 C<B<description()>>
+
+C<description()> returns description string of this module.
+
+    print Sisimai::Bite::Email::Activehunter->description;
+
+=head2 C<B<smtpagent()>>
+
+C<smtpagent()> returns MTA name.
+
+    print Sisimai::Bite::Email::Activehunter->smtpagent;
+
+=head2 C<B<scan(I<header data>, I<reference to body string>)>>
+
+C<scan()> method parses a bounced email and return results as a array reference.
+See Sisimai::Message for more details.
+
+=head1 AUTHOR
+
+azumakuniyuki
+
+=head1 COPYRIGHT
+
+Copyright (C) 2014-2018 azumakuniyuki, All rights reserved.
+
+=head1 LICENSE
+
+This software is distributed under The BSD 2-Clause License.
+
+=cut
+